Hallo Leute,
in einem anderen Forum wurde gefragt, was die eingeklammerten Werte
hinter der Schriftgrösse bedeuten. Und wie man sie wieder wegkriegt.
Dieses Thema wurde hier zwar schon behandelt (zum Beispiel:
http://www.hilfdirselbst.ch/foren/Schriftgr%F6%DFen_in_Klammern_P215922.html#215922 und es gibt sogar
ein AppleScript, welches bei Gruppierungen hilfreich ist.
Hier eine erweiterte Fassung des Scripts, welche auch einzelne
Rahmen, die eventuell mit ausgewählt worden sind, berücksichtigt.
Wichtig ist, dass die Objekte mit dem Auswahlwerkzeug (= schwarzer
Pfeil) ausgewählt wurden. Sonst werden Gruppen nicht behandelt.
Und es gibt leider keine Möglichkeit, per Script festzustellen,
welches Werkzeug aktiv ist.
Das folgende Script kann auch hier heruntergeladen werden:
http://www.fachhefte.ch / Den Link "AppleScripts" anklicken, die Ordner
"mac_os_x_d" und "indesign_cs2" öffnen. Das Stuffit-Archiv heisst
"TextAttrSkalieren.sit".
--TextAttrSkalieren_01d.scpt
(*
Dieses Script dient zum Zuweisen der aktuellen Schriftgrösse, welche
bei skalierten Rahmen in Klammern hinter dem Ausgangswert steht.
*)
tell application "Adobe InDesign CS2"
activate
if (count of documents) is 0 then
display dialog "Ein Dokument öffnen." buttons ¬
"OK" default button 1 with icon 0
error number -128
end if
tell document 1
set curSel to selection
if curSel is {} then
display dialog "Es ist nichts ausgewählt." buttons ¬
"OK" default button 1 with icon 0
error number -128
end if
set selType to class of item 1 of curSel
if selType is rectangle or selType is graphic line then
display dialog "Nur Textrahmen auswählen." buttons ¬
"OK" default button 1 with icon 0
error number -128
else if selType is not text frame and selType is not group then
display dialog "Rahmen mit dem Auswahlwerkzeug auswählen." buttons ¬
"OK" default button 1 with icon 0
error number -128
end if
repeat with curItem in curSel
if class of curItem is group then
my scaleGroupAttr(curItem)
else if class of curItem is text frame then
my scaleTextAttr(curItem)
end if
end repeat
end tell
display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 1
end tell
on scaleGroupAttr(curGroup)
tell application "Adobe InDesign CS2"
tell curGroup
try
transform group contents
end try
end tell
set allFrames to every page item of curGroup
repeat with curFrame in allFrames
if class of curFrame is group then
my scaleGroupAttr(curFrame)
else if class of curFrame is text frame then
my scaleTextAttr(curFrame)
end if
end repeat
end tell
end scaleGroupAttr
on scaleTextAttr(curItem)
tell application "Adobe InDesign CS2"
tell curItem
try
scale text attributes
end try
end tell
end tell
end scaleTextAttr
Gruss, Hans
