hallo

bin neu hier und hab mich heute erstmals in applescript versucht. problem ist in einem vorhandenen dokumente stile zu verändern. bei den character styles klappt das alles, nur bei den paragraph styles nicht. wenn ich da versuche die character attribute für open type umzusetten stürzt quark (7.3) ab. hab auch ein neues testdokument angelegt: dasselbe. weiss da jemand etwas dazu?

wäre für hilfe dankbar

schöne grüße
volkmar

Hallo Volkmar,

herzlich willkommen im PAGE-Forum! :-)

Welche Attribute möchtest Du ändern? Und wie sieht Dein Code aus?

(Ich befürchte aber, dass nichts zu machen ist: Soeben, beim ersten Versuch, ist mir XPress auch abgestürzt ...)

Gruss, Hans

danke für die bemühung. ich dachte auch es muss ein bug sein.
werd jetzt mal nachsehn ob ich vielleicht die character attributes irgendwie von den paragraph stiles getrennt kriege. wenn alles character styles wären, würde es ja klappen.

hier nochmal das stück code:

tell application "QuarkXPress Passport"
    activate
    repeat with i from 1 to count of documents
        tell document i   
            tell style spec "Bildtext_10pt"
                set properties to {character attributes:{font:"Corpid E1s Cd Regular"}}
                set properties to {character attributes:{open type style:{OT tabular figures:{true}, OT lining figures:{true}}}}
            end tell
        end tell
    end repeat
end tell

wenn du ne idee hast ob das irgendwie geht, alles an stilen in charcter styles zu wandeln, wär mir sehr geholfen.

danke und gruß
volkmar

Hallo Volkmar,

das Problem scheint nur mit Absatz-Stilvorlagen aufzutreten. Ich habe es aber nicht ausführlich getestet.

Mit diesem Script gelingt es, eine Zeichen-Stilvorlage zu ändern:
---
tell document 1 of application "QuarkXPress 7.31"
   tell character spec "test_char"
      try
         set properties to {open type style:{OT tabular figures:true}}
      end try
   end tell
end tell
---

Aber wenn derselbe Befehl an eine Absatz-Stilvorlage gerichtet ist ...
---
tell document 1 of application "QuarkXPress 7.31"
   tell style spec "test"
      tell character attributes
         try
            set properties to {open type style:{OT tabular figures:true}}
         end try
      end tell
   end tell
end tell
---
... dann löst es wieder einen Absturz aus.

Es sieht so aus, als ob Du von jeder Absatz-Stilvorlage eine Zeichen-Stilvorlage erzeugen müsstest:
1. Absatz-Stilvorlage einem Text zuweisen.
2. Control-Taste niederhalten, in der Palette den Zeiger auf den ausgewählten Namen richten, die Maustaste drücken und im Kontextmenü den Artikel "Bearbeiten XXX..." wählen.
3. Im Dialog beim lokalen Menü "Zeichenstil" den Artikel "Neu..." wählen.
4. Im sich öffnenden Dialog einen Namen eintippen und mit "OK" bestätigen.

Vielleicht könnte man für diese Aktionen ein entsprechendes Script entwickeln.

Gruss, Hans

hallo und danke nochmal für die bisherige hilfe.

ich bastel jetzt an so einer umgehung. ich bin aber nicht der held im scripten. character style anlegen geht, aber wie verpass ich ihm die properties aus dem paragraph style? er wills einfach nicht machen. wahrscheinlich irgendwas mit der syntax. müsste doch mit einer elegante zeile möglich sein.

gruß

volkmar

so, ich glaube ich bin auf dem richtigen weg:

tell application "QuarkXPress Passport"
    activate
    global neuerNamen
    global proppies
    repeat with i from 1 to count of documents
        tell document i
            repeat with j from 1 to count of style specs
                set neuerNamen to name of style spec j
                try
                    make new character spec at beginning with properties {name:neuerNamen}
                    set proppies to properties of character attributes of style spec neuerNamen
                    set character style of style spec neuerNamen to neuerNamen
                    tell character spec neuerNamen
                        set properties to proppies
                        set properties to {style:{class:text style info, on styles:{plain}, off styles:{bold, italic, underline, outline, shadow, superscript, subscript, superior, strikethrough, all caps, small caps, word underline}}}
                    end tell
                end try
            end repeat
        end tell
    end repeat
end tell

was mich irritiert ist, wieso nimmt er die styles nicht korrekt mit? ich muss das im moment mit dieser zusatzanweisung lösen.


gruß
volkmar

Hallo Volkmar,

das Problem mit den Stilen habe ich gestern auch bemerkt. Allerdings ist es so, dass beim Zuweisen der gespeicherten Zeichenattribute, die Stile Kursiv, Schattiert, Versalien, Hochgestellt und Index aktiviert werden.

Abhilfe: Mit set style to plain den Stil auf "Normal" zurücksetzen und dann mit einer Schleife die vorher gespeicherten Stile der aktuellen Stilvorlage zuweisen.

Mit show document i wird das zu behandelnde Dokument in den Vordergrund geholt. Die nächste Zeile lautet deshalb tell document 1 (mit i würde sonst immer dasselbe Dokument angesprochen).
---
tell application "QuarkXPress 7.31"
   activate
   repeat with i from 1 to count of documents
      show document i
      tell document 1
         repeat with j from 1 to count of style specs
            tell style spec j
               set curName to name
               set charProps to properties of character attributes
               set curStyles to on styles of (get style of charProps)
            end tell
            try
               make character spec at end with properties {name:curName}
               tell character spec curName
                  set properties to charProps
                  set style to plain
                  repeat with k from 1 to count of curStyles
                     set style to item k of curStyles
                  end repeat
               end tell
               tell style spec j
                  set character style to curName
               end tell
            end try
         end repeat
      end tell
   end repeat
   display dialog "Fertig." buttons "OK" default button 1 with icon 1 giving up after 1
end tell
---

Gruss, Hans

vielen dank, das hilft immer wenn ein profi das nochmal aufdröselt.
ich bin ja inzwischen auch ein stück weiter, das mit den stilen klappt soweit auch. leider ist das ausgangsdokument noch mit lokalen formatierungen durchwirkt. wenn ich das ignoriere, siehts eigentlich relativ gut aus. aber man muss höllisch aufpassen das man die ausnahmen nicht übersieht. ich hab mal dein script "stilvorlagen neu zuweisen" drüber gejagt. das wäre natürlich dann die saubere lösung, aber dann sieht man erst was alles lokal bearbeitet wurde. wahrscheinlich liesse sich das auch noch per script in neue stile rauswandeln aber ich schätze mal da wird der aufwand etwas zu groß. ich bau denen noch die gewünschten farbwechsel ein und werds erstmal so probieren.
ich weiss noch nicht genau wieviel dokumente da bearbeitet werden müssen. vielleicht lohnt der aufwand doch noch. mal sehn.

einstweilen aber mal vielen dank für die prompte hilfe

gruß
volkmar